Quelquepart

Blog d'un développeur ABAP

Posts Tagged abap objet

Cure de rajeunissement pour AL11

Feb 4

Posted by Sebastien in Général | 17 Comments

Je vous conseille d’aller lire cet article à sa nouvelle adresse : Cure de rajeunissement pour AL11

Le travail sur un datawarehouse nous confronte régulièrement à des injections de fichier. Et sur SAP, nous ne sommes pas gâté niveau outils…
J’entendais souvent mes collègues râler à propos de la transaction AL11, la seule chose dont nous disposons en standard pour naviguer sur le serveur SAP.

J’ai parcouru la toile à la recherche d’une solution de remplacement mais ne fut pas convaincu par ce que j’y ai trouvé, aussi j’ai pris mon courage (et mon clavier) à deux mains afin de réaliser ma propre solution : plus complète, plus lisible et avec l’ergonomie qui me sied (mais je ne crache pas dans leur soupe, j’ai d’ailleurs repris leur manière de déterminer l’icone relatif a chaque type de fichier).

ZAL11 display local and server file explorer

ZAL11 display local and server file explorer

Entièrement graphique, le programme “ZAL11″ (tout simplement ;-) ) vous permettra de naviguer sur le serveur SAP, mais également :

  • D’ouvrir les fichiers avec votre application par défaut sur votre PC (excel pour les CSV par exemple)
  • D’ouvrir les fichiers avec un éditeur de texte sur votre PC
  • De télécharger ou télédécharger des fichiers
  • De gérer les fichiers/répertoires du serveur (ajout, copie, déplacement, renommage)
  • De compresser (tar+bz2) ou décompresser (zip, tar, gz, bz2) des fichiers et répertoires sur le serveur
  • De copier dans le presse-papier le chemin d’un fichier sur le serveur, ou d’accéder directement au répertoire d’un chemin contenu dans le presse-papier.

La gestion des raccourcis serveur de AL11 est conservée (et débuggée ;-) )
Vu qu’il s’agit de manipulation sur le serveur, chaque action demande une confirmation via un popup qui récapitule ce qui est en train d’être fait.

ZAL11 File and folder context menu

ZAL11 File and folder context menu

Le code a été écrit dans une optique de sécurité, de maintenabilité et de respect des normes de développement usuels. Il est entièrement documenté en anglais (25% de commentaires ajoutés par rapport au code brut).
La principale “entorse” aux règles est que le code est fourni dans un seul pavé de 3500 lignes au lieu d’être découpé en includes (top, class, pbo, pai, form). C’est volontaire afin de n’avoir qu’un seul code source à fournir. Néanmoins chaque partie est clairement délimitée et il ne devrait pas falloir plus d’une minute à un développeur pour recréer les includes nécessaires. Pour la même raison de simplicité de partage, aucune classe de message n’a été créée.

Télécharger ZAL11 (compatible ECC) (Si vous n’arrivez pas à télécharger le fichier : click droit puis enregistrer la cible sous… et n’oubliez pas que vous aurez besoin de SAPLINK pour l’installer ensuite)

Tags: , , , , , ,

Afficher un ALV objet sans créer d’écran (screen painter)

Jan 24

Posted by Sebastien in Général | Comments off

Je vous conseille d’aller lire cet article à sa nouvelle adresse : Afficher un ALV objet sans créer d’écran (screen painter)

Lassé de créer un écran ne contenant qu’un custom control, avec PBO et PAI rachitiques uniquement pour afficher votre grid ALV objet ? La classe cl_gui_container contient nativement des attributs qui permettent de s’en passer ! Encore faut-il le savoir, ce qui est maintenant votre cas ;-)
En effet, au lieu de créer tout d’abord un objet container puis d’indiquer cet objet en parent de l’objet alv, utilisez directement cl_gui_container=>screen0 comme parent pour votre ALV !

PROGRAM test.
DATA : o_alv      TYPE REF TO cl_gui_alv_grid,
       t_sflight  TYPE TABLE OF sflight.

* Definition d'un écran de sélection vide
SELECTION-SCREEN : BEGIN OF SCREEN 1001,
                   END OF SCREEN 1001.

* Remplissage de la table de données pour l'ALV
SELECT * FROM sflight INTO TABLE t_sflight.

* Creation de l'objet alv directement rattaché au premier screen
CREATE OBJECT o_alv
  EXPORTING
    i_parent = cl_gui_container=>screen0.

* Passage des données a l'ALV
CALL METHOD o_alv->set_table_for_first_display
  EXPORTING
    i_structure_name = 'SFLIGHT'
  CHANGING
    it_outtab        = t_sflight.

* Affichage de l'écran, l'ALV apparait !
CALL SELECTION-SCREEN 1001.

Cette astuce améliore au passage la portabilité de votre code (pas de screen/status/title à gérer).

Tags: , , , ,

MOVE-CORRESPONDING à la sauce objet

Jan 7

Posted by Sebastien in Général | Comments off

Je vous conseille d’aller lire cet article à sa nouvelle adresse : MOVE-CORRESPONDING à la sauce objet

L’instruction 

MOVE-CORRESPONDING A TO B

permet de copier les champs d’une structure A vers les champs d’une structure B, pour peu qu’ils portent le même nom. Les champs de A n’existant pas dans B sont ignorés.

Vous pouvez écrire la même chose en utilisant field symbol et abap objet :

lo_descr ?= cl_abap_typedescr=>describe_by_data( A ).
LOOP AT lo_descr->components INTO ls_compx.
  CONCATENATE 'A-' ls_compx-name INTO lv_fsname.
  ASSIGN (lv_fsname) TO <lfs_component1>.
  CHECK sy-subrc = 0
  CONCATENATE 'B-' ls_compx-name INTO lv_fsname.
  ASSIGN (lv_fsname) TO <lfs_component2>.
  CHECK sy-subrc = 0
  <lfs_component2> = <lfs_component1>.
ENDLOOP.

Et la vous dites, Waou c’est merveilleux, mais pourquoi irai-je remplacer une ligne de code simple, lisible et éprouvée contre 10 lignes aux performances incertaines ?

Dans l’exemple simpliste présenté ici cela n’a aucun intérêt. En revanche, quand les structures A et B sont assez larges, et qu’il y a des règles spéciales à appliquer sur certains champs, cela peut s’avérer intéressant : quand vous ne voulez pas écraser un champs de B par son homonyme de A ou que vous voulez mettre un champs de A dans un champs portant un autre nom dans B…

A ne surtout pas utiliser de manière systématique, mais peut être utile lorsque les règles sont complexes ;-)

Tags: ,

BW3 : Suppression des données d’un cube avec ses dimensions

Nov 4

Posted by Sebastien in Général | No Comments

Je vous conseille d’aller lire cet article à sa nouvelle adresse : BW3 : Suppression des données d’un cube avec ses dimensions

L’accroissement de la taille des dimensions sur BW3 est un problème classique de l’équipe de maintenance. En effet, lors d’un cube chargé en “full” quotidiennement, le contenu du cube est généralement purgé au début du chargement.

Malheureusement cette étape de la process chain ne propose pas d’option pour supprimer également le contenu des dimensions. Ainsi leur taille croit jour après jour, finissant si l’on y prend pas garde par dépasser la volumétrie du cube lui même, entrainant ainsi une dégradation des performances de plus en plus prononcée, ainsi qu’un accroissement de la taille occupée par le cube sur le disque.

SAP a finit par se rendre compte de ce problème, et la version BI7 propose en option de supprimer le contenu des dimensions lors de la suppression du contenu d’un cube.
Pour les malheureux qui n’ont pas encore migré, il n’y a pas de solution standard, à part effectuer régulièrement une suppression manuelle du contenu des dimensions (prévoir un réveil a 3h du matin pour intervenir juste avant le chargement de la process chain…)

J’ai donc réalisé un petit ABAP spécifique afin de réaliser cette opération. Il vient remplacer le processus de suppression de contenu de cube dans les process chain. Il suffit de préciser en paramètre d’entrée le nom du cube pour que son contenu ainsi que ses dimensions soient supprimées.

Télécharger le code source de ZCUBE_DELETE

Tags: , , , , , ,

Classe CL_GUI_FRONTEND_SERVICES

Nov 3

Posted by Sebastien in Fonction | 1 Comment

Je vous conseille d’aller lire cet article à sa nouvelle adresse : Classe CL_GUI_FRONTEND_SERVICES

Derrière ce nom se cache une véritable trousse à outils de méthodes toutes plus utiles les unes que les autres. En effet SAP a décidé de regrouper au sein d’une même classe toutes les “fonctions” de dialogue avec le pc de l’utilisateur (aussi appelé “poste client”).
Terminé les WS_UPLOAD ou autre GUI_UPLOAD (que SAP indique depuis longtemps comme obsolète), place à la méthode upload.

L’usage est simplifié au maximum, afin que même les développeurs fermés à l’abap objet puissent les utiliser. Inutile de créer un objet ou déclarer quoi que ce soit, vous pouvez appeler directement la méthode qui vous intéresse dans la classe CL_GUI_FRONTEND_SERVICES, de la même manière que vous appelleriez une fonction classique.

Ci dessous un tableau récapitulant les principales méthodes, avec un exemple d’utilisation.

Méthode Description Code exemple
CLIPBOARD_EXPORT Exporter des données dans le presse-papier Windows 
DATA : s_line(100),
       t_line LIKE TABLE OF s_line,
       i_rc TYPE i.

APPEND 'Test envoi presse-papier' TO t_line.

CALL METHOD cl_gui_frontend_services=>clipboard_export
  IMPORTING
    data         = t_line
  CHANGING
    rc           = i_rc
  EXCEPTIONS
    OTHERS       = 0.
WRITE i_rc.
CLIPBOARD_IMPORT Importer des données du presse-papier Windows 
DATA : s_line(100),
       t_line LIKE TABLE OF s_line,
       i_length TYPE i.

CALL METHOD cl_gui_frontend_services=>clipboard_import
  IMPORTING
    data         = t_line
    length       = i_length
  EXCEPTIONS
    OTHERS       = 0.

LOOP AT t_line INTO s_line.
  WRITE / s_line.
ENDLOOP.
DIRECTORY_BROWSE Affiche un popup windows de sélection de répertoire sur le poste local
Ne fonctionne pas avec le noyau 4.6c		 
DATA : w_folder TYPE string,
       w_title TYPE string,
       w_init TYPE string.

w_title = 'Rechercher le dossier'.
w_init = 'C:\'.

CALL METHOD cl_gui_frontend_services=>directory_browse
  EXPORTING
    window_title    = w_title
    initial_folder  = w_init
  CHANGING
    selected_folder = w_folder
  EXCEPTIONS
    OTHERS          = 0.

WRITE w_folder.
DIRECTORY_CREATE Créer un répertoire sur le poste client 
DATA : w_dir TYPE string,
       i_rc TYPE i.

w_dir = 'C:\Nouveau Rep inexistant'.

CALL METHOD cl_gui_frontend_services=>directory_create
  EXPORTING
    directory = w_dir
  CHANGING
    rc        = i_rc
  EXCEPTIONS
    OTHERS    = 0.

WRITE i_rc.
DIRECTORY_DELETE Supprimer un répertoire sur le poste client 
DATA : w_dir TYPE string,
       i_rc TYPE i.

w_dir = 'C:\Nouveau Rep inexistant'.

CALL METHOD cl_gui_frontend_services=>directory_delete
  EXPORTING
    directory = w_dir
  CHANGING
    rc        = i_rc
  EXCEPTIONS
    OTHERS    = 0.

WRITE i_rc.
DIRECTORY_EXIST Tester si un répertoire existe sur le poste client 
DATA : w_dir TYPE string,
       w_rc.

w_dir = 'C:\guixt'.

CALL METHOD cl_gui_frontend_services=>directory_exist
  EXPORTING
    directory = w_dir
  RECEIVING
    result    = w_rc
  EXCEPTIONS
    OTHERS    = 0.

WRITE w_rc. "X si existe, space si n'existe pas
DIRECTORY_LIST_FILES Liste les fichiers d’un répertoire 
DATA : s_line(100),
       t_line LIKE TABLE OF s_line,
       w_dir TYPE string,
       i_count TYPE i.

w_dir = 'C:\'.

CALL METHOD cl_gui_frontend_services=>directory_list_files
  EXPORTING
    directory                   = w_dir
    filter                      = '*.TXT'
*    FILES_ONLY                  =
*    DIRECTORIES_ONLY            =
  CHANGING
    file_table                  = t_line
    count                       = i_count
  EXCEPTIONS
    OTHERS                      = 0.

WRITE i_count.
LOOP AT t_line INTO s_line.
  WRITE / s_line.
ENDLOOP.
ENVIRONMENT_GET_VARIABLE Lecture d’une variable d’environnement Windows
Ne semble pas fonctionner sur noyau SAP_BASIS 6.20		 
DATA : w_var TYPE string,
       w_val TYPE string.

w_var = 'OS'.

CALL METHOD cl_gui_frontend_services=>environment_get_variable
  EXPORTING
    variable = w_var
  CHANGING
    value    = w_val
  EXCEPTIONS
    OTHERS   = 0.

WRITE w_val.
ENVIRONMENT_SET_VARIABLE Modification d’une variable d’environnement Windows
Ne semble pas fonctionner sur noyau SAP_BASIS 6.20		 
DATA : w_var TYPE string,
       w_val TYPE string,
       i_rc TYPE i.

w_var = 'NEWVAR'.
w_val = 'TEST'.
CALL METHOD cl_gui_frontend_services=>environment_set_variable
  EXPORTING
    variable = w_var
    value    = w_val
  CHANGING
    rc       = i_rc
  EXCEPTIONS
    OTHERS   = 0.

WRITE i_rc.
EXECUTE Exécute une application sur le poste client 
DATA : w_appl TYPE string,
       w_param TYPE string.

w_appl = 'C:\WINDOWS\NOTEPAD.EXE'.
w_param = 'C:\boot.ini'.

CALL METHOD cl_gui_frontend_services=>execute
  EXPORTING
    application            = w_appl
    parameter              = w_param
  EXCEPTIONS
    OTHERS                 = 0.
FILE_DELETE Supprimer un fichier sur le poste client 
DATA : w_file TYPE string,
       i_rc TYPE i.

w_file = 'C:\test.txt'.

CALL METHOD cl_gui_frontend_services=>file_delete
  EXPORTING
    filename = w_file
  CHANGING
    rc       = i_rc
  EXCEPTIONS
    OTHERS   = 0.

WRITE i_rc.
FILE_EXIST Tester si un fichier existe sur le poste client 
DATA : w_file TYPE string,
       w_rc.

w_file = 'C:\test.txt'.

CALL METHOD cl_gui_frontend_services=>file_exist
  EXPORTING
    file   = w_file
  RECEIVING
    result = w_rc
  EXCEPTIONS
    OTHERS = 0.

WRITE w_rc.
FILE_OPEN_DIALOG Affiche un popup windows de sélection de fichier sur le poste local 
DATA : w_titre TYPE string,
       w_file TYPE string,
       w_dir TYPE string,
       t_file TYPE filetable,
       s_file LIKE LINE OF t_file,
       i_rc TYPE i.

w_titre = 'Selection de fichier'.
w_file = 'test.txt'.
w_dir = 'C:\guixt'.

CALL METHOD cl_gui_frontend_services=>file_open_dialog
  EXPORTING
    window_title      = w_titre
    default_filename  = w_file
    initial_directory = w_dir
  CHANGING
    file_table        = t_file
    rc                = i_rc
  EXCEPTIONS
    OTHERS            = 0.

WRITE i_rc.
LOOP AT t_file INTO s_file.
  WRITE / s_file.
ENDLOOP.
FILE_SAVE_DIALOG Affiche un popup windows de sélection de fichier sur le poste local
(avec confirmation si le fichier existe déjà)		 
DATA : w_titre TYPE string,
       w_file TYPE string,
       w_dir TYPE string,
       w_name TYPE string,
       w_path TYPE string,
       w_fp TYPE string.

w_titre = 'Selection de fichier pour sauvegarde'.
w_file = 'test.txt'.
w_dir = 'C:\guixt'.

CALL METHOD cl_gui_frontend_services=>file_save_dialog
  EXPORTING
    window_title      = w_titre
    default_file_name = w_file
    initial_directory = w_dir
  CHANGING
    filename          = w_name
    path              = w_path
    fullpath          = w_fp
  EXCEPTIONS
    OTHERS            = 0.

WRITE : / w_name, / w_path, / w_fp.
GUI_DOWNLOAD Télécharger un fichier sur le poste client 
DATA : w_file type string,
       s_file type string,
       t_file like table of s_file.

w_file = 'C:\test.txt'.
s_file = 'Test de contenu de fichier'.
append s_file to t_file.

CALL METHOD cl_gui_frontend_services=>gui_download
  EXPORTING
    filename                = w_file
    FILETYPE                = 'ASC'
  changing
    data_tab                = t_file
  EXCEPTIONS
    others                  = 0.
GUI_UPLOAD Charger un fichier depuis le poste client 
DATA : w_file TYPE string,
       s_file TYPE string,
       t_file LIKE TABLE OF s_file.

w_file = 'C:\test.txt'.

CALL METHOD cl_gui_frontend_services=>gui_upload
  EXPORTING
    filename = w_file
  CHANGING
    data_tab = t_file
  EXCEPTIONS
    OTHERS   = 0.

LOOP AT t_file INTO s_file.
  WRITE / s_file.
ENDLOOP.
REGISTRY_DELETE_KEY Supprimer une clé de registre sur le poste client
Ne semble pas fonctionner sur noyau SAP_BASIS 6.20
REGISTRY_DELETE_VALUE Supprimer une valeur de registre sur le poste client
Ne semble pas fonctionner sur noyau SAP_BASIS 6.20
REGISTRY_GET_VALUE Lire une valeur de registre sur le poste client
Ne semble pas fonctionner sur noyau SAP_BASIS 6.20
REGISTRY_SET_VALUE Modifier une valeur de registre sur le poste client
Ne semble pas fonctionner sur noyau SAP_BASIS 6.20

Tags: , ,